PRIM_PDF.AutoTable (PRIM_PDF.AutoTable)

祖先 - オブジェクト (PRIM_OBJT)

詳細

PDF ジェネレーター機能を使って、事前にフォーマットされたテーブルをPDF 形式のレポート内に作成することができます。

例

AutoTable を作成します。 

     Evtroutine Handling(#FindContacts.completed)
        Define_Com Class(#PRIM_PDF) Name(#pdf)
        Define_Com Class(#PRIM_PDF.AutoTable) Name(#Table) Reference(*DYNAMIC) Theme(Striped) Columncount(3)
        Define_Com Class(#PRIM_PDF.AutoTableColumn) Name(#LastNameCol) Reference(*DYNAMIC)
        Define_Com Class(#PRIM_PDF.AutoTableColumn) Name(#FirstNameCol) Reference(*DYNAMIC)
        Define_Com Class(#PRIM_PDF.AutoTableColumn) Name(#CellPhoneCol) Reference(*DYNAMIC)
        Define_Com Class(#PRIM_PDF.AutoTableRow) Name(#Row) Reference(*DYNAMIC) 

        #pdf.start
        #pdf.setFont Font('Roboto') Style(Bold)
        #pdf.setFontSize Size(16)
        #pdf.text Text('My Contacts Report') Left(14) Top(10) 

        * AutoTableの作成
        #Table <= #pdf.CreateAutoTable 

        * テーブル レベルのプロパティ
        #Table.StartY := 15
        #Table.Overflow := LineBreak
        #Table.HeadFontName := 'Helvetica'
        #Table.HeadHAlign := Left
        #Table.HeadVAlign := Middle
        #Table.HeadFontSize := 12
        #Table.HeadFontStyle := Bold 

        * テーブル列の定義
        #LastNameCol <= #Table.CreateColumn
        #LastNameCol.HeadCaption := 'Last name'
        #Table.AddColumn Column(#LastNameCol) 

        #FirstNameCol <= #Table.CreateColumn
        #FirstNameCol.HeadCaption := 'First name'
        #Table.AddColumn Column(#FirstNameCol) 

        #CellPhoneCol <= #Table.CreateColumn
        #CellPhoneCol.HeadCaption := 'Cell Phone'
        #CellPhoneCol.HeadHAlign := Center
        #CellPhoneCol.HAlign := Center
        #Table.AddColumn Column(#CellPhoneCol) 

        * テーブル データの追加
        Selectlist Named(#xContactsList)
           #Row <= #Table.CreateRow 

           #Row.addCell Value(#xContactLastName)
           #Row.addCell Value(#xContactFirstName)
           #Row.addCell Value(#xContactMobilePhone) 

           #Table.AddRow Row(#Row)
        Endselect 

        * AutoTableの書き込み
        #Table.Write 

        * PDFレポートの保存
        #pdf.save Filename('MyContacts.pdf')
     Endroutine

プロパティ

イベント

メソッド

参照

すべてのコンポーネント クラス
テクニカル リファレンス