List Column - ColumnPinned Property
Pin the column to the left or right hand sides of the list
Member of List Column (PRIM_LIST.Column)
Data Type - Enumeration
Details
The ColumnPinned property allows columns to positioned to the left or right side of the main list body.
Pinned columns scroll vertically but are not subject to horizontal scrolling, remaining visible at all times.
Allowed Values
Enum Value |
Description |
Left |
The column will be pinned to the left side of the list |
None |
The column will be positioned int he main body of the list |
Right |
The column will be pinned to the right side of the list |
Example
Click the column headings to see the effect of column(s) being pinned to the left.
Begin_Com Role(*EXTENDS #PRIM_WEB) Height(752) Width(1032) Theme(#SYS_THEME<2015Blue>) LayoutManager(#Layout1)
Define_Com Class(#PRIM_TBLO) Name(#Layout1)
Define_Com Class(#PRIM_TBLO.Row) Name(#LayoutRow1) DisplayPosition(1) Parent(#Layout1)
Define_Com Class(#PRIM_TBLO.Column) Name(#LayoutColumn1) DisplayPosition(1) Parent(#Layout1)
Define_Com Class(#PRIM_TBLO.Item) Name(#LayoutItem1) Column(#LayoutColumn1) Manage(#List) Parent(#Layout1) Row(#LayoutRow1)
Define_Com Class(#PRIM_LIST) Name(#List) DisplayPosition(1) Left(0) Parent(#COM_OWNER) TabPosition(1) Top(0) Height(752) Width(1032) RowHeight(29)
Define_Com Class(#PRIM_LIST.Number) Name(#ColumnNumber) ColumnWidth(130) DisplayPosition(1) Increment(1) Parent(#List) Source(#xDemoNumber) Wrap(False)
Define_Com Class(#PRIM_LIST.Number) Name(#ColumnNumber2) ColumnWidth(340) DisplayPosition(2) Increment(1) Parent(#List) Source(#xDemoNumber_2) Wrap(False)
Define_Com Class(#PRIM_LIST.String) Name(#ColumnString) ColumnWidth(768) DisplayPosition(3) Parent(#List) Source(#xDemoCaption)
Evtroutine Handling(#Com_owner.CreateInstance)
Begin_Loop Using(#xDemoNumber) To(100)
#xDemoNumber_2 := #xDemoNumber * 100
#xDemoCaption := ("List item &1").Substitute( #xDemoNumber.AsString )
Add_Entry To_List(#List)
End_Loop
Endroutine
Evtroutine Handling(#ColumnNumber.ColumnClick #ColumnNumber2.ColumnClick #ColumnString.ColumnClick) Com_Sender(#Sender)
If (#Sender.ColumnPinned = Left)
#Sender.ColumnPinned := None
Else
#Sender.ColumnPinned := Left
Endif
Endroutine
End_Com